Mathematica does not have the concept of row or column vectors like you may be used to. The concept isn't really necessary either and is just a convention to visualize the dot product (although I know there are people that vehemently object to this statement).

In dot products like $M\cdot\vec{x}$ and $\vec{x}^{^\top}\cdot M$ Mathematica uses $\vec{x}$ as your column and row vector automatically. Both are entered in Mathematica as the same list.

```
{{1, 2}, {3, 4}}.{5, 6}
(* {17, 39} *)
{5, 6}.{{1, 2}, {3, 4}}
(* {23, 34} *)
```

Of course, this means that the length of the vector must be equal to the number of columns in the matrix in the former case, and to the number of rows in the latter case.

So, this doesn't work (2x3 matrix):

```
{{1, 2, 1}, {3, 4, 1}}.{5, 6}
```

During evaluation of Dot::dotsh: Tensors {{1,2,1},{3,4,1}} and {5,6} have incompatible shapes. >>

```
(* {{1, 2, 1}, {3, 4, 1}}.{5, 6} *)
```

and this works (3x2 matrix):

```
{{1, 2}, {3, 4}, {1, 1}}.{5, 6}
(* {17, 39, 11} *)
```

If you insist on using column and row vectors, you can *mimic* them by using similarly looking *matrices*. The matrix equivalent of a *column* vector would be `{{x1}, {x2},...,{xn}}`

. The equivalent of a *row* vector would be `{{x1, x2,...,xn}}`

. If you use `MatrixForm`

or `TableForm`

they display just like column and row vectors would, except that they are still matrices in disguise (nx1 and 1xn ones, respectively). Those matrices behave in dot products just like their row and column vector brethren would in languages that have them, but remember, *they are not necessary at all in Mathematica*.

```
{{1, 2}, {3, 4}}.{{5}, {6}}
(* {{17}, {39}} *)
{{5, 6}}.{{1, 2}, {3, 4}}
(* {{23, 34}} *)
```

The above code typeset in `TraditionalForm`

(just `Ctrl`+`Alt`+`T` of the above lines) displays as:

The main disadvantage of this technique is having to deal with extra curly brackets that have to be removed when you want to use the resulting vector as a list, and the fact that you have to change the brackets depending on the position in the dot product. Additionally, there are functions that expect Mathematica vectors (simple lists) that won't work when provided with their matrix emulations.

5To make it work:

`j={{1,2,3}}`

. You can check then dimensions with`Dimensions[j] -> {1,3}`

. – Kuba – 2014-01-13T22:34:34.1206That is not an 1 by 3 matrix but a length 3 vector. Mathematica works with general tensors of arbitrary dimensions, not only 2-dimensional matrices like many MATLAB-inspired systems. Mathematica supports true 1-dimensional vectors. This is described on the doc page of

`Dot`

, take a look underDetails. – Szabolcs – 2014-01-13T22:55:01.6301In Wolfram, it is convenient that one does not have to distinguish row vectors from column vectors. However, that convenience is also confusion-prone. So, either you can decide to not distinguish at all, or you do distinguish completely. Then the problem rises because you let

`i`

be a column vector but meanwhile you let`j`

be the superposition of row vector and column vector --- that is, you do the distinguishing, but not to the full extent. – Αλέξανδρος Ζεγγ – 2017-12-04T13:51:25.017