Sorry to use Presentations again but it has many convenient features for complex variables, Riemann spheres and associated dynamics. I wouldn't use Graph but would specify the vertices and lines directly in the complex plane. So here are some points:

```
<< Presentations`
zpoints = {-2, -1 + I, -1 - I, I, -I, 1} + 5/2;
```

The following specifies a network of lines on the points.

```
znet = {ComplexLine@zpoints[[{1, 2, 4, 6, 5, 3, 1}]],
ComplexLine@zpoints[[{2, 3}]],
ComplexLine@zpoints[[{4, 5}]]};
```

Next we draw the network in the complex plane.

```
Draw2D[
{znet,
ComplexCirclePoint[#, 3, Black, Orange] & /@ zpoints},
ImageSize -> 250]
```

Next we draw the network on the Riemann sphere. ColoredRiemannSphere draws a Riemann sphere with some annotation and it can be customized in various ways. StereographicMap maps items in the complex plane onto the sphere. FineGrainLines breaks up the lines into a number of segments. This is important so that the lines can bend to fit the sphere. If one just gives the endpoints the lines would cut through the interior of the sphere. ViewRiemann is a set of plot directives that show the sphere to best advantage.

```
Draw3DItems[
{ColoredRiemannSphere[],
StereographicMap[znet // FineGrainLines[0.1, 4]]},
ViewRiemann,
ImageSize -> 250]
```

Finally, here is a dynamic display. The left hand plot is the network in the complex plane with the vertices defined by six movable locators. The right hand plot is the same network on the Riemann sphere. The plot on the sphere responded essentially instantly to the locators.

```
DynamicModule[{pt1, pt2, pt3, pt4, pt5, pt6, net, calcNet},
{pt1, pt2, pt3, pt4, pt5, pt6} =
ToCoordinates[{-2, -1 + I, -1 - I, I, -I, 1}];
calcNet[p1_, p2_, p3_, p4_, p5_, p6_] :=
(net = {Line[{p1, p2, p4, p6, p5, p3, p1}],
Line[{p2, p3}], Line[{p4, p5}]} // FineGrainLines[0.1, 3]);
calcNet[pt1, pt2, pt3, pt4, pt5, pt6];
phrase[
Draw2D[
{Dynamic@{net},
DrawLocators[{pt1, pt2, pt3, pt4, pt5, pt6},
CirclePointLocator[3, Red],
calcNet[pt1, pt2, pt3, pt4, pt5, pt6]]},
Frame -> True,
PlotRange -> 3,
ImageSize -> 250],
Spacer[5],
Draw3DItems[
{ColoredRiemannSphere[],
Dynamic@StereographicMap[net]},
ViewRiemann,
ImageSize -> 250]]
]
```

If the lines cross in the plane they will certainly cross on the sphere.

I'm making the assumption that to show that a graph is planar really just boils down to showing that its ability to be drawn on the sphere is enough to show planar-ness. – Loie Benedicte – 2013-08-04T22:51:19.497

Wait... Its projection onto the $\mathbb{R}^2$ would have a crossing... Wouldn't it... – Loie Benedicte – 2013-08-04T22:53:39.223

Hmm... My initial thought seems a little daft because what I"m trying to do is "show that each graph is planar by redrawing it so that no edges cross," but I don't think this complicated approach is really necessary... – Loie Benedicte – 2013-08-04T22:55:45.013

The graph is drawn in a plane without crossings to begin with. And the question makes it seem that that is the ultimate object as well. Is that right? Is it necessary to visualize the graph on a sphere? – Michael E2 – 2013-08-04T23:02:19.020

No, but I would like to be able to visualize graphs with crossing on a sphere. – Loie Benedicte – 2013-08-04T23:10:41.313

Related: http://mathematica.stackexchange.com/questions/23793/stereographic-projection, http://mathematica.stackexchange.com/questions/20291/showing-a-rectangular-plot-on-an-almost-closed-sphere/20306#20306

– Michael E2 – 2013-08-05T00:12:01.700