How to inject an evaluated expression into a held expression?

22

15

I know that there are methods to structurally manipulate held expressions (discussed e.g. here), but I failed to apply those for this particular problem:

(Hold[{3, 4, 5 | 6}] /. (Verbatim@Alternatives)[x__] :> RandomChoice@List@x)
Hold[{3, 4, RandomChoice[{5, 6}]}]

The code should replace any Alternatives in the held expression with an appropriate choice from the alternatives, in this case either 5 or 6, i.e. it should evaluate the replacement.

István Zachar

Posted 2012-03-07T01:46:09.400

Reputation: 44 135

Question was closed 2013-07-28T07:09:19.623

@rm-rf & WReach, is there any particular reason why Verbatim is used in each answer? This will do too: /. x_Alternatives :> RuleCondition@RandomChoice@(List @@ x) or /. x_Alternatives :> With[{eval = RandomChoice@(List @@ x)}, eval /; True]). – Kuba – 2013-11-22T09:47:05.173

@Kuba Verbatim is only used becase I wanted to pass on arguments as Sequence[5, 6] instead of 5|6 as in a replacement, the latter could possibly match more than one thing. It's not necessary but I guess they all tried to comply with my original specification. Your's is equally good. – István Zachar – 2013-11-22T09:59:18.097

Ok, thanks, I just wasn't sure if I get everything :) – Kuba – 2013-11-22T10:07:18.040

@kguler but HoldFirst is not a "held expression" wrapper, it's an attribute. – FJRA – 2012-03-07T02:08:17.587

@FJRA, just realized why OP wanted to use Hold rather than HoldFirst or HoldRest or HoldAll (and deleted my previous comment before I saw your explanation) – kglr – 2012-03-07T02:14:48.653

Answers

24

Here are a couple of alternatives to Trott-Strzebonski in @R.M's answer:

Hold[{3,4,5|6}] /.
  Verbatim[Alternatives][x__] :> RuleCondition@RandomChoice@List@x

Hold[{3, 4, 5}]

Hold[{3,4,5|6}] /.
  Verbatim[Alternatives][x__] :> Block[{}, RandomChoice@List@x /; True]

Hold[{3, 4, 6}]

They operate on the same principle as Trott-Strzebonski (i.e. RuleCondition), but express the effect in different ways.

WReach

Posted 2012-03-07T01:46:09.400

Reputation: 62 787

1I was tempted to post this answer, but decided to wait for you, as the proper one to do it :). +1. – Leonid Shifrin – 2012-03-07T06:44:34.837

22

This is a case where the Trott-Strzebonski in-place evaluation trick is useful. You use With to inject inside your held expression as:

(Hold[{3, 4, 5 | 6}] /. (Verbatim@Alternatives)[x__] :> 
    With[{eval = RandomChoice@List@x}, eval /; True])

Out[1]= Hold[{3, 4, 5}]

You should definitely read this post by Leonid, that gives you a good insight into how this works, but in short, using Condition or /; forces the evaluation of eval when the condition is True (i.e., always) and then injected arbitrarily deep using With.

rm -rf

Posted 2012-03-07T01:46:09.400

Reputation: 85 395

Just a note the talk title is "Working with Unevaluated Expressions" in case the link to wolfram library changes again in the future. – xslittlegrass – 2015-07-19T16:24:53.627